#!/bin/sh
#
# CDDL HEADER START
#
# The contents of this file are subject to the terms of the
# Common Development and Distribution License, Version 1.0 only
# (the "License").  You may not use this file except in compliance
# with the License.
#
# You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
# or http://www.opensolaris.org/os/licensing.
# See the License for the specific language governing permissions
# and limitations under the License.
#
# When distributing Covered Code, include this CDDL HEADER in each
# file and include the License file at usr/src/OPENSOLARIS.LICENSE.
# If applicable, add the following below this CDDL HEADER, with the
# fields enclosed by brackets "[]" replaced with your own identifying
# information: Portions Copyright [yyyy] [name of copyright owner]
#
# CDDL HEADER END
#
#
# Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
# Use is subject to license terms.
#

#
# Stack munging utility, written by David Powell.
#
# Takes the output of multiple ::findstack dcmds and groups similar 
# stacks together, presenting the most common ones first.  To use:
#
# > ::walk thread | ::findstack ! munges
#

foo="d"
bar=""
while getopts ab i; do
	case $i in
	b)	foo="s/\[\(.*\) ]/\1/";;
	a)	bar="s/+[^(]*//";;
	esac
done

sed "
/^P/ d
/(..*)$/ d
s/^s.*read \(.*:\).*$/\1/
t a
/^\[/ $foo
s/^ .* \(.*\)$/ \1/
$bar
H
$ !d
s/.*//
:a
x
1 d
s/\n//g
" | sort -t : -k 2 | uniq -c -f 1 | sort -rn  | sed '
s/) /)\
	/g
s/^ *\([^ ]*\) *\(.*\): */\1	##################################  tp: \2\
	/
1 !s/^/\
/
'