#!/usr/sbin/dtrace -s -q

/*
 * CDDL HEADER START
 *
 * The contents of this file are subject to the terms of the
 * Common Development and Distribution License, Version 1.0 only
 * (the "License").  You may not use this file except in compliance
 * with the License.
 *
 * You can obtain a copy of the license at 
 * http://www.opensolaris.org/os/licensing.
 * See the License for the specific language governing permissions
 * and limitations under the License.
 *
 * When distributing Covered Code, include this CDDL HEADER in each
 * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
 * If applicable, add the following below this CDDL HEADER, with the
 * fields enclosed by brackets "[]" replaced with your own identifying
 * information: Portions Copyright [yyyy] [name of copyright owner]
 *
 * CDDL HEADER END
 */
/*
 * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
 * Use is subject to license terms.
 */

/*
 * How long (in nanosecs) did threads in a process and it's children(s) run
 * local vs remote.
 * ./lgrp_local-remote.d <pid> > log.out
 */

syscall::fork1:return
/
progenyof($1) && pid != $1
/
{
	child_trace[pid] = 1;
}

syscall::vfork:return
/
progenyof($1) && pid != $1
/
{
	child_trace[pid] = 1;
}

syscall::forkall:return
/
progenyof($1) && pid != $1
/
{
	child_trace[pid] = 1;
}

	
sched:::on-cpu
/
progenyof($1) && 
(pid == $1 || child_trace[pid]) &&
(curthread->t_lpl->lpl_lgrpid != lgrp)
/
{
	self->remotetime[curthread] = timestamp;
}

sched:::off-cpu
/
progenyof($1) && 
(pid == $1 || child_trace[pid]) &&
(curthread->t_lpl->lpl_lgrpid != lgrp) &&
self->remotetime[curthread] != 0
/
{
	@lgrplat[curthread] = sum(timestamp - self->remotetime[curthread]);
	self->remotetime[curthread] = 0;
}

sched:::on-cpu
/
progenyof($1) && 
(pid == $1 || child_trace[pid]) &&
(curthread->t_lpl->lpl_lgrpid == lgrp)
/
{
	self->localtime[curthread] = timestamp;
}

sched:::off-cpu
/
progenyof($1) && 
(pid == $1 || child_trace[pid]) &&
(curthread->t_lpl->lpl_lgrpid == lgrp) &&
self->localtime[curthread] != 0
/
{
	@lgrphome[curthread] = sum(timestamp - self->localtime[curthread]);
	self->localtime[curthread] = 0;
}

END
{
	printa("\nThread 0x%p ran locally for : %@u nsecs\n", @lgrphome);
	printa("\nThread 0x%p ran remotely for : %@u nsecs \n", @lgrplat);
}