#!/usr/sbin/dtrace -s -q

/*
 * CDDL HEADER START
 *
 * The contents of this file are subject to the terms of the
 * Common Development and Distribution License, Version 1.0 only
 * (the "License").  You may not use this file except in compliance
 * with the License.
 *
 * You can obtain a copy of the license at 
 * http://www.opensolaris.org/os/licensing.
 * See the License for the specific language governing permissions
 * and limitations under the License.
 *
 * When distributing Covered Code, include this CDDL HEADER in each
 * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
 * If applicable, add the following below this CDDL HEADER, with the
 * fields enclosed by brackets "[]" replaced with your own identifying
 * information: Portions Copyright [yyyy] [name of copyright owner]
 *
 * CDDL HEADER END
 */

/*
 * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
 * Use is subject to license terms.
 */

/*
 * Given the pid of a process.
 * Observe thread rehomed from home lgroup to different lgroup for process
 * and it's children(s).
 * ./lgrp_rehomed.d <pid>  > log.out
 */

syscall::fork1:return
/
progenyof($1) && pid != $1
/
{
	child_trace[pid] = 1;
}

syscall::vfork:return
/
progenyof($1) && pid != $1
/
{
	child_trace[pid] = 1;
}

syscall::forkall:return
/
progenyof($1) && pid != $1
/
{
	child_trace[pid] = 1;
}

lgrp_move_thread:entry
/
progenyof($1) && 
(pid == $1 || child_trace[pid])
/
{
	self->thread = (kthread_t *)arg0;
	self->thlgrp = (lpl_t *)((kthread_t *)arg0)->t_lpl;
	self->lgrpld = (lpl_t *)arg1;
}

lgrp_move_thread:return
/
self->lgrpld && self->thlgrp &&
self->lgrpld != self->thlgrp
/
{
	@lgrpquan[self->thread, self->thlgrp->lpl_lgrpid] =
		quantize(self->lgrpld->lpl_lgrpid);
	self->thread = 0;
	self->thlgrp = 0;
	self->lgrpld = 0;
}

END
{
	printa("\nThread 0x%p from Home lgrp %x rehomed to New lgrp : %@x  \n",
		 @lgrpquan);
}